Version: Next

Contracts

A contract is a collection of type definitions, data (its state), and code (its functions), that is stored in the contract storage area of an account.

Contracts are where all composite types interfaces for these types have to be defined. Therefore, an object of one of these types cannot exist without having been defined in a deployed Cadence contract.

Contracts can be deployed to accounts, updated, and removed from accounts using the contracts object of authorized accounts. See the account contracts page for more information about these operations.

Contracts are types. They are similar to composite types, but are stored differently than structs or resources and cannot be used as values, copied, or moved like resources or structs.

Contracts stay in an account's contract storage area and can only be added, updated, or removed by the account owner with special commands.

Contracts are declared using the contract keyword. The keyword is followed by the name of the contract.

access(all)
contract SomeContract {
    // ...
}

Contracts cannot be nested in each other.

access(all)
contract Invalid {
    // Invalid: Contracts cannot be nested in any other type.
    //
    access(all)
    contract Nested {
        // ...
    }
}

One of the simplest forms of a contract would just be one with a state field, a function, and an init function that initializes the field:

access(all)
contract HelloWorld {
    // Declare a stored state field in HelloWorld
    //
    access(all)
    let greeting: String
    // Declare a function that can be called by anyone
    // who imports the contract
    //
    access(all)
    fun hello(): String {
        return self.greeting
    }
    init() {
        self.greeting = "Hello World!"
    }
}

Transactions and other contracts can interact with contracts by importing them at the beginning of a transaction or contract definition.

Anyone could call the above contract's hello function by importing the contract from the account it was deployed to and using the imported object to call the hello function.

import HelloWorld from 0x42
// Invalid: The contract does not know where hello comes from
//
log(hello())        // Error
// Valid: Using the imported contract object to call the hello
// function
//
log(HelloWorld.hello())    // prints "Hello World!"
// Valid: Using the imported contract object to read the greeting
// field.
log(HelloWorld.greeting)   // prints "Hello World!"
// Invalid: Cannot call the init function after the contract has been created.
//
HelloWorld.init()    // Error

There can be any number of contracts per account and they can include an arbitrary amount of data. This means that a contract can have any number of fields, functions, and type definitions, but they have to be in the contract and not another top-level definition.

// Invalid: Top-level declarations are restricted to only be contracts
//          or contract interfaces. Therefore, all of these would be invalid
//          if they were deployed to the account contract storage and
//          the deployment would be rejected.
//
access(all) resource Vault {}
access(all) struct Hat {}
access(all) fun helloWorld(): String {}
let num: Int

Another important feature of contracts is that instances of resources and events that are declared in contracts can only be created/emitted within functions or types that are declared in the same contract.

It is not possible create instances of resources and events outside the contract.

The contract below defines a resource interface Receiver and a resource Vault that implements that interface. The way this example is written, there is no way to create this resource, so it would not be usable.

// Valid
access(all) contract FungibleToken {
    access(all) resource interface Receiver {
        access(all) balance: Int
        access(all) fun deposit(from: @{Receiver}) {
            pre {
                from.balance > 0:
                    "Deposit balance needs to be positive!"
            }
            post {
                self.balance == before(self.balance) + before(from.balance):
                    "Incorrect amount removed"
            }
        }
    }
    access(all) resource Vault: Receiver {
        // keeps track of the total balance of the accounts tokens
        access(all) var balance: Int
        init(balance: Int) {
            self.balance = balance
        }
        // withdraw subtracts amount from the vaults balance and
        // returns a vault object with the subtracted balance
        access(all) fun withdraw(amount: Int): @Vault {
            self.balance = self.balance - amount
            return <-create Vault(balance: amount)
        }
        // deposit takes a vault object as a parameter and adds
        // its balance to the balance of the Account's vault, then
        // destroys the sent vault because its balance has been consumed
        access(all) fun deposit(from: @{Receiver}) {
            self.balance = self.balance + from.balance
            destroy from
        }
    }
}

If a user tried to run a transaction that created an instance of the Vault type, the type checker would not allow it because only code in the FungibleToken contract can create new Vaults.

import FungibleToken from 0x42
// Invalid: Cannot create an instance of the `Vault` type outside
// of the contract that defines `Vault`
//
let newVault <- create FungibleToken.Vault(balance: 10)

Account access

Contracts can access the account they are deployed to: contracts have the implicit field named account which is only accessible within the contract.

let account: auth(Storage, Keys, Contracts, Inbox, Capabilities) &Account`,

The account reference is fully entitled, so grants access to the account's storage, keys, contracts, etc.

For example, this gives the contract the ability to write to the account's storage when the contract is initialized.

init(balance: Int) {
    self.account.storage.save(
        <-create Vault(balance: 1000),
        to: /storage/initialVault
    )
}

Contract interfaces

Like composite types, contracts can have interfaces that specify rules about their behavior, their types, and the behavior of their types.

Contract interfaces have to be declared globally. Declarations cannot be nested in other types.

Contract interfaces may not declare concrete types (other than events), but they can declare interfaces. If a contract interface declares an interface type, the implementing contract does not have to also define that interface. They can refer to that nested interface by saying {ContractInterfaceName}.{NestedInterfaceName}

// Declare a contract interface that declares an interface and a resource
// that needs to implement that interface in the contract implementation.
//
access(all) contract interface InterfaceExample {
    // Implementations do not need to declare this
    // They refer to it as InterfaceExample.NestedInterface
    //
    access(all) resource interface NestedInterface {}
    // Implementations must declare this type
    //
    access(all) resource Composite: NestedInterface {}
}
access(all) contract ExampleContract: InterfaceExample {
    // The contract doesn't need to redeclare the `NestedInterface` interface
    // because it is already declared in the contract interface
    // The resource has to refer to the resource interface using the name
    // of the contract interface to access it
    //
    access(all) resource Composite: InterfaceExample.NestedInterface {
    }
}

Account access​

Contract interfaces​

Account access

Contract interfaces